#define sprite_edit_begin
// sprite_edit_begin
// By Leif902 with modifications by Xot
//
// Arguments:
//           Argument0 - The Sprite to Edit
//           Returns   - A session ID to give to sprite_edit_end (as a string)
// Notes:
//       After this function is called, all drawing events will be
//       drawn onto the chosen sprite, the sprite will only be saved
//       however when sprite_edit_end is called.

{
    var sprite,a,w,h,n,xoff,yoff,surface,i;
    sprite = argument0;
    a = draw_get_alpha();
    w = sprite_get_width(sprite);
    h = sprite_get_height(sprite);
    n = sprite_get_number(sprite);
    xoff = sprite_get_xoffset(sprite);
    yoff = sprite_get_yoffset(sprite);
    surface = surface_create(w*n,h);
    surface_set_target(surface);
    draw_clear(c_black);
    draw_set_blend_mode_ext(bm_one,bm_zero);
    draw_set_alpha(1);
    for(i=0; i<n; i+=1) {
        draw_sprite(sprite,i,i*w+xoff,yoff);
    }
    draw_set_blend_mode(bm_normal);
    draw_set_alpha(a);
    return (string(surface)+':'+string(sprite));
}
#define sprite_edit_end
// sprite_edit_end
// By Leif902 with modifications by Xot
//
// Arguments:
//           Argument0 - The string id returned by sprite_edit_begin

{
    var session,p,surface,sprite,w,h,n,prec,tran,smth,load,xoff,yoff,temp,i;
    session = argument0
    p = string_pos(':',session);
    surface = real(string_copy(session,1,p-1));
    sprite = real(string_copy(session,p+1,10));
    w = sprite_get_width(sprite);
    h = sprite_get_height(sprite);
    n = sprite_get_number(sprite);
    prec = sprite_get_precise(sprite);
    tran = sprite_get_transparent(sprite);
    smth = sprite_get_smooth(sprite);
    load = sprite_get_preload(sprite);
    xoff = sprite_get_xoffset(sprite);
    yoff = sprite_get_yoffset(sprite);
    temp = sprite_create_from_surface(surface,0,0,w,h,prec,tran,smth,load,xoff,yoff);
    for(i=1; i<n; i+=1) {
        sprite_add_from_surface(temp,surface,w*i,0,w,h);
    }
    sprite_assign(sprite,temp);
    sprite_delete(temp);
    surface_reset_target();
    surface_free(surface);
}